通常，在ASP中進行的form表單提交的數據都被寫進數據庫管理系統中去，如果你想要你的數據是方便攜帶的數據，你可以把它寫進一個XML文件中去。這種方法是跨平台的，因此你所收集的信息不需要進行轉換。
為了實現上面的想法，你必須先利用Microsoft XMLDOM建立一個XML文件，Microsoft XMLDOM對象有一個擴展對象庫，它可以創建組成XML文件所需要的元素、屬性、屬性值。
當XMLDOM對象實例化以後，必須對各個元素進行引用來建立XML的結構，下面的例子就是先建立根元素，並把她追加到XML文件中；然後創建各個子元素，並追加元素的屬性值。最後保存為XML文件。
實例化 Microsoft XMLDOM Object:
<%
Dim objDom
Dim objRoot
Dim objChild1
Dim objChild2
Dim objPI
Set objDom = Server.CreateObject("Microsoft.XMLDOM")
Set objRoot = objDom.createElement("rootElement")
objDom.appendChild objRoot
Set objChild1 = objDom.createElement("childElement1")
objRoot.appendChild objChild1
Set objChild2 = objDom.createElement("childElement2")
objRoot.appendChild objChild2
Set objPI = objDom.createProcessingInstruction("XML","version=''1.0''")
objDom.insertBefore objPI, objDom.childNodes(0)
objDom.Save "c:\MyXMLDoc.XML"
%>
一旦你保存了文件，用IE5+打開後，樣式如下[當然，屬性還沒有被賦值]：
MyXMLDoc.XML:
<?XML version="1.0"?>
<rootElement>
<childElement1 />
<childElement2 />
</rootElement>
下面我們來看看怎樣利用這個對象來存儲用戶的輸入信息。
首先建立輸入表單的頁面。EnterContact.Html:
<Html>
<head>
<title>
通訊信息
</title>
</head>
<body>
<form action="processForm.ASP" method="post">
<h3>請輸入您的通訊信息：</h3>
姓 名: <input type="text" id="Name" name="姓名"><br>
性 別: <input type="text" id="sexName" name="性別"><br>
地 址: <input type="text" id="address" name="地址"><br>
工作單位: <input type="text" id="company" name="工作單位"><br>
電 話: <input type="text" id="phone" name="電話"><br>
電子郵件: <input type="text" id="email" name="電子郵件"><br>
<input type="submit" id="btnSub" name="btnSub" value="提交"><br>
</form>
</body>
</Html>
然後編寫ASP代碼，遍歷表單元素，並把輸入的信息寫進XML文件。processForm.ASP:
<%
''--------------------------------------------------------------------
''函數 "ConvertFormtoXML"接收傳遞的參數。
''strXMLFilePath - XML存放的物理地址。
''strFileName - 要保存的XML文件的名字。
''--------------------------------------------------------------------
Function ConvertFormtoXML(strXMLFilePath, strFileName)
''定義本地變量.
Dim objDom
Dim objRoot
Dim objFIEld
Dim objFIEldValue
Dim objattID
Dim objattTabOrder
Dim objPI
Dim x
''實例化Microsoft XMLDOM對象.
Set objDom = server.CreateObject("Microsoft.XMLDOM")
objDom.preserveWhiteSpace = True
''創建XML文檔的根元素contact，並追加到XML文檔中。
Set objRoot = objDom.createElement("通訊錄")
objDom.appendChild objRoot
''遍歷Request對象Form元素的集合。
For x = 1 To Request.Form.Count
If instr(1,Request.Form.Key(x),"btn") = 0 Then
''創建元素 "fIEld".
Set objField = objDom.createElement("fIEld")
''創建屬性 "id".
Set objattID = objDom.createAttribute("id")
''設定id屬性的值等於Form中各元素的值。
objattID.Text = Request.Form.Key(x)
''setAttributeNode 方法把id屬性值追加到fIEld元素。
objFIEld.setAttributeNode objattID
''創建屬性taborder。
Set objattTabOrder = objDom.createAttribute("taborder")
''設定taborder的屬性值
objattTabOrder.Text = x
''把taborder的屬性值追加到fIEld元素中去。
objFIEld.setAttributeNode objattTabOrder
''創建一個新的元素fIEld_value.
Set objFieldValue = objDom.createElement("fIEld_value")
''賦值
objFIEldValue.Text = Request.Form(x)
''追加fIEld元素為根元素的子元素。
objRoot.appendChild objFIEld
''追加fIEld_value做為子元素的內容
objField.appendChild objFIEldValue
End If
Next
''創建XML聲明
Set objPI = objDom.createProcessingInstruction("XML", "version=''1.0'' encoding=''gb2312''")
''把xml生命追加到XML文檔
objDom.insertBefore objPI, objDom.childNodes(0)
''保存XML文件
objDom.save strXMLFilePath & "\" & strFileName
''釋放所有對象所引用的值
Set objDom = Nothing
Set objRoot = Nothing
Set objFIEld = Nothing
Set objFIEldValue = Nothing
Set objattID = Nothing
Set objattTabOrder = Nothing
Set objPI = Nothing
End Function
''發生錯誤時繼續執行
On Error Resume Next
''調用函數ConvertFormtoXML把文件存放到指定的文件目錄和文件名。
ConvertFormtoXML "D:\ASPexam","Contact.XML"
''如果發生錯誤，提示用戶，否則報告成功。
If err.number <> 0 then
Response.write("保存form值出現錯誤！！！")
Else
Response.write("提交成功！！")
End If
%>
用IE5+打開Contact.XML文件，會看到如下所示:
<?XML version="1.0" encoding="gb2312" ?>
<通訊錄>
<fIEld id="姓名" taborder="1">
<field_value>孟憲會</fIEld_value>
</fIEld>
<fIEld id="性別" taborder="2">
<field_value>男</fIEld_value>
</fIEld>
<fIEld id="地址" taborder="3">
<field_value>北京建外大街甲24號</fIEld_value>
</fIEld>
<fIEld id="工作單位" taborder="4">
<field_value>環球.中國</fIEld_value>
</fIEld>
<fIEld id="電話" taborder="5">
<field_value>13910309xxx</fIEld_value>
</fIEld>
<fIEld id="電子郵件" taborder="6">
<field_value>amxh@21cn.com</fIEld_value>
</fIEld>
</通訊錄>